orの優先度は低い

perl -le 'my $a = 0 or 1; print $a'
=> 0

perl -le 'my $a = 0 || 1; print $a'
=> 1

何も考えずに書くと、秘かに狂った結果が出ていて、きっと痛い目に遭う。

しかし、perlは、何も考えずに書けるように、そして、コードを読む方はあまり重視されない方向性でこれまで使われてきた言語である。

勿論、読みやすく書く努力はperlでも可能だが……。

危険な正規表現

 "hoge" =~ /^hoge$/

は当然マッチする。しかし、この正規表現は、実は、

 "hoge\n" =~ /^hoge$/

にもマッチしてしまう！
末尾に改行が来て欲しくない場合は、以下のようにすれば、マッチしなくなる

 "hoge\n" =~ /^hoge\z/

perlスクリプトをプロファイリング

 perl -d:DProf スクリプトファイル名

とすると、カレントディレクトリに「tmon.out」というファイルを吐くので、

 dprofpp tmon.out

execの罠と利用法

bk-exec

localを使って、動的スコープを実現できる

この動的スコープを最もよく使う場面は、%ENVや%SIGを一時的に変更したい時。
但し、dynamic-windの無いperlでは、高階関数(関数を返す関数)で返した関数内から、localで動的スコープを見ようとしても、高階関数が結果関数を返した時点で、localの値は元に戻されてしまっていて、どうしようもない事に注意する事！

gotoの魔術的用法

以下の二つはどっちも同じっぽい

 goto &hoge;

 goto \&hoge;

以下の記法で、gotoの魔術的用法を最大に利用できる

 my $sub = sub { ‥… }; # 予め無名関数を作っておき、
 goto $sub; # 関数refでgotoする

但し、引数は、予め、@_に自分で入れておく必要がある
逆に言うと、gotoを使う場合は、引数渡し以外の方法でパラメータを渡した方が使い勝手が良い（つまり、オブジェクト的用法とはあまり相性がよくない）
gotoを使う事で、容易に継続渡しスタイルを実現できる（手でcps変換をやっているのと同じ）
当然、末尾再帰の最適化としても使える
- 無名関数を変数に入れて自分自身を呼び出す際、変数の定義順に注意する必要がある。
  - 具体的には、
    - my $hoge = sub { …‥; goto $hoge } # schemeで言うならlet
  - では駄目（subの中ではまだ$hogeは存在しない）。
    - my $hoge; $hoge = sub { …‥; goto $hoge } # schemeで言うならletrec
  - としなくてはならない。
  - ※しかしこれでは$hogeは循環参照になってしまい、GCがリファレンスカウント方式のperlでは、メモリリークになってしまう！この$hogeを使った後は必ず$hoge=undefを行い、循環参照を確実に解除する事。
  - 最近では、 Sub::Recursive というモジュールがあるので、これをletrec代わりに使うのがいいと思う。しかし突如$RECが出現したり、複数の相互再帰関数定義時が気持ち悪い。

refスライス

ハッシュスライス

 my $hashref = { aaa => 123, bbb => 456, ccc => 789, };
 my $values = [ @{$hashref}{qw[ aaa ccc ]} ];

配列スライス

 my $arrayref = [ 0, 1, 2, 3, 4, 5, 6, 7, 8, 9 ];
 my $values = [ @{$arrayref}[3..7] ];

シグナルハンドラの操作

 local $SIG{TERM} = \&killDelayed;

のように、動的スコープを使ってシグナルハンドラを設定する事で、「この関数内でだけシグナルハンドラを設定して、関数を抜けたら元の状態に戻したい」という事が簡単に実現できる。

省略とscalar/listの罠

「return;」は、空リストを返している（結果、それがundefに見えているだけ）。
なので、以下のような場合、引数が一個ずれてしまう！

 sub hoge { return; }
 my ($a, $b, $c) = (1, hoge(), 2);
 # $aには1が入るが、$bには2が入り、$cはundefとなる

一個の値であるところの「undef」を返したい場合は、ちゃんと、「return undef;」と書く事。

同様の問題として、以下の二つの違いについて、考えよ。
```
perl -le 'print reverse "123"'
```
```
perl -le 'print scalar reverse "123"'
```
- （答え：scalarによって、reverse評価時のwantarrayの値が違う（printは引数にリストを期待する為））

間接オブジェクト記法の罠（perl_quizより）

 print (1+3)*2;
 # この結果は8ではなく4になる。つまり、以下のように認識されている。
 # (print(1+3))*2;
 # エラーが出ないので、発見しづらい。要注意。

間接オブジェクト記法の罠その二

 use IO::Handle;
 print STDOUT "hoge\n"; # 正しい。

 my $fh = \*STDOUT;
 print $fh "fuge\n"; # 正しい。

 my $this = { fh => \*STDOUT };
 # print $this->{fh} "mage\n"; # コレは正しくない！！！
 # 正しくするには、次の二つのどちらかにする
 print {$this->{fh}} "mage\n"; # 間接オブジェクト記法
 $this->{fh}->print("mage\n"); # 矢印オブジェクト記法

perlは、はまりポイントの多さは、rubyやpythonの比では無い、と、仕事で使っていて、常日頃から思っていた。

仕事では、まだperlを業務としては使ってはいるものの、「perlは、一生使っていける言語か？」という問いに対して、自分は少なくとも「yes」とは絶対に答えられない(※perl6は含まない、という事で)。

そして、言語とは、何年も使わなくてはマスターできないものである、という話であり、自分もそれを体感している。

それならば、将来には使わなくなるような言語は早く捨てて、将来に渡って自分が長く使いそうな言語を、さっさと使い始めた方がいいのではないか？

今のところ、「今後、一生使っていける言語のナンバーワン」は、自分の中では、Lispが群を抜いて一位。

なので、perlを捨てて、Lispで仕事をしたいと、常々思う。

しかし……。

最終更新 : 2010/01/06 17:55:50 JST

bk-perl